Latest posts for the topic "[Windows]如何定時自動備份整個網站目錄到遠端伺服器"

[Windows]如何定時自動備份整個網站目錄到遠端伺服器

andowson — GMT

:!:設計理念
1.先將要備份的目錄壓縮起來（節省傳輸時間）
2.然後再ftp到遠端的伺服器去（建立日期目錄）
3.定時自動執行（如每日凌晨三點）

首先，3可用Windows附屬應用程式=>系統工具=>排定的工作來完成，我們最後設定即可。
1和2則需要寫支DOS batch程式來完成，假設叫做remote_backup_web.bat。底下是該bat檔案的內容
[code=bat]
rem ---------------------------------------------------------------------------
rem Backup web application to remote host
rem
rem $Id: remote_backup_web.bat 2007-02-07 21:24:43Z andowson $
rem ---------------------------------------------------------------------------

@echo off
rem Find out web server's IP address
ipconfig | findstr "Address" > ip1.txt
for /f "tokens=1-2 delims=:" %%i in (ip1.txt) do echo %%j > ip2.txt
for /f "tokens=1-2 delims= " %%i in (ip2.txt) do (set ip=%%i)
del ip1.txt
del ip2.txt

rem Get today's year, month, day
for /f "tokens=1-3 delims=/ " %%a in ('date /t') do (set year=%%a& set month=%%b& set day=%%c)

rem Modify the following line for your environment
set TARGET=C:\Inetpub\wwwroot\demoweb
set TARGETNAME=demoweb
set BACKUPDIR=D:\backup
set BACKUPFILE=%BACKUPDIR%\%year%\%TARGETNAME%_%ip%_%year%%month%%day%.zip
set LOGFILE=%TARGETNAME%_backup.log

echo. | date | findstr "現在日期" >> %LOGFILE%
echo. | time | findstr "現在時間" >> %LOGFILE%

rem Compress the target directory before ftp
zip -r %BACKUPFILE% %TARGET%\*

if not exist %BACKUPDIR%\%year% mkdir %BACKUPDIR%\%year%

if not exist %BACKUPFILE% goto nofile
goto ftpsession

:nofile
echo [FAILURE] can't find %BACKUPFILE% >> %LOGFILE%
echo.>> %LOGFILE%
goto end

:ftpsession
for /f "tokens=1-3 delims= " %%i in (ftp.cfg) do (set FTPSERVER=%%i&set USERNAME=%%j&set PASSWORD=%%k)
echo open %FTPSERVER% > ftpscript.txt
echo user %USERNAME% %PASSWORD% >> ftpscript.txt
echo mkdir %year%%month%%day% >> ftpscript.txt
echo cd %year%%month%%day% >> ftpscript.txt
echo bi >> ftpscript.txt
echo put %BACKUPFILE% >> ftpscript.txt
echo bye >> ftpscript.txt

echo ---=== ftp session begins ===--->> %LOGFILE%
echo ftp %BACKUPFILE% to %FTPSERVER% >> %LOGFILE%

ftp -i -n < ftpscript.txt >> %LOGFILE%

echo ---=== ftp session ends ===--->> %LOGFILE%
echo. |time | findstr "現在時間">> %LOGFILE%
echo.>> %LOGFILE%

del ftpscript.txt

set TARGET=
set TARGETNAME=
set BACKUPDIR=
set BACKUPFILE=
set LOGFILE=
set FTPSERVER=
set USERNAME=
set PASSWORD=

:end
[/code]

其中zip指令(取自[url=ftp://ftp.info-zip.org/pub/infozip/win32/]Info-ZIP[/url]發行之免費軟體）並非Windows內建的指令，請由本站下載，放到C:\Windows目錄下

Windows內建的FTP指令說明可以透過執行ftp --usage指令得到：
[code=plain]
ftp --usage

Transfers files to and from a computer running an FTP server service
(sometimes called a daemon). Ftp can be used interactively.

FTP [-v] [-d] [-i] [-n] [-g] [-s:filename] [-a] [-w:windowsize] [-A] [host]

-v Suppresses display of remote server responses.
-n Suppresses auto-login upon initial connection.
-i Turns off interactive prompting during multiple file
transfers.
-d Enables debugging.
-g Disables filename globbing (see GLOB command).
-s:filename Specifies a text file containing FTP commands; the
commands will automatically run after FTP starts.
-a Use any local interface when binding data connection.
-A login as anonymous.
-w:buffersize Overrides the default transfer buffer size of 4096.
host Specifies the host name or IP address of the remote
host to connect to.

Notes:
- mget and mput commands take y/n/q for yes/no/quit.
- Use Control-C to abort commands.[/code]

另外我把ftp的參數檔存放在ftp.cfg，內容如下
[code]remotehost username password[/code]
remotehost:請改成您的遠端主機IP(需有啟動FTP Server)
username:請改成您的FTP帳號
password:請改成您的FTP密碼

執行完會在執行目錄下產生一個logfile，可供debug用。

最後，遠端伺服器需先建立好對應的帳號及密碼，如有修改請記得回來改ftp.cfg

參考資料：
[url=http://www.microsoft.com/taiwan/technet/columns/profwin/28-monad.mspx]易學易用的 Windows PowerShell[/url]

回覆:[Windows]如何定時自動備份整個網站目錄到遠端伺服器

winglee007 — GMT

首先謝謝你,我用了這個bat,超好用的^^

但有一個問題想問一下,如果我在壓縮的時候,可以有方法在這bat檔加上密碼才上傳到ftp嗎?

因為我們要處理會計的文件,很機密的,謝謝

回覆:[Windows]如何定時自動備份整個網站目錄到遠端伺服器

andowson — GMT

要加上密碼也是可以的，只要將原本的zip.exe換一個可以加密碼的壓縮軟體執行檔即可，例如7-Zip這個免費又可以加上密碼的壓縮軟體的7z.exe。
1.到[url]http://www.7-zip.org/[/url]下載安裝用的exe檔
2.執行下載的exe檔安裝
3.安裝完成後，將C:\Program Files\7-Zip下的7z.exe複製到C:\Windows\System32目錄下。

相關的參數可以在命令列下執行7z獲得：
[code=plain]7-Zip 4.57 Copyright (c) 1999-2007 Igor Pavlov 2007-12-06

Usage: 7z [...] [...]
[<@listfiles...>]

a: Add files to archive
b: Benchmark
d: Delete files from archive
e: Extract files from archive (without using directory names)
l: List contents of archive
t: Test integrity of archive
u: Update files to archive
x: eXtract files with full paths

-ai[r[-|0]]{@listfile|!wildcard}: Include archives
-ax[r[-|0]]{@listfile|!wildcard}: eXclude archives
-bd: Disable percentage indicator
-i[r[-|0]]{@listfile|!wildcard}: Include filenames
-m{Parameters}: set compression Method
-o{Directory}: set Output directory
-p{Password}: set Password
-r[-|0]: Recurse subdirectories
-scs{UTF-8 | WIN | DOS}: set charset for list files
-sfx[{name}]: Create SFX archive
-si[{name}]: read data from stdin
-slt: show technical information for l (List) command
-so: write data to stdout
-ssc[-]: set sensitive case mode
-ssw: compress shared files
-t{Type}: Set type of archive
-v{Size}[b|k|m|g]: Create volumes
-u[-][p#][q#][r#][x#][y#][z#][!newArchiveName]: Update options
-w[{path}]: assign Work directory. Empty path means a temporary directory
-x[r[-|0]]]{@listfile|!wildcard}: eXclude filenames
-y: assume Yes on all queries[/code]

以下是一個執行命令的範例，會將目前整個目錄壓縮起來存到c:\backup.zip檔案，並加上密碼secret。
[code]7z a -psecret c:\backup.zip *[/code]

所以原來程式簡易的修改方式如下：
將第29行的程式碼取代為：
[code="bat; first-line:29"]set ZIPPASSWORD=secret
7z a -p%ZIPPASSWORD% %BACKUPFILE% %TARGET%\* [/code]

回覆:[Windows]如何定時自動備份整個網站目錄到遠端伺服器

starzine — GMT

:thumbup:謝謝你～這個程式幫助很大。
但是想請教一下，dos的指令，有沒有辦法抓取系統日前一日的日期呢？因為找了很久都找不到任何相關資訊，所以想請教一下，謝謝！

回覆:[Windows]如何定時自動備份整個網站目錄到遠端伺服器

andowson — GMT

底下是我在網路上蒐尋[google]DOS batch 取得前一天的日期[/google]得到的資料，供您參考
[code=bat]
@echo off
:: 作者： namejm 出自：cn-dos
:: 求N天前的日期
:: 日期可以帶星期，但是，必須以年月日的順序排列
:: 年份必須是四位，否則會出錯
@echo off
:Main
cls
set day=%date%
set days=0
echo.&echo.
echo 當前日期是：%day%
echo.&set /p input= 請指定要追溯的天數：
setlocal enabledelayedexpansion
:: 提取日期
for /f "tokens=1-3 delims=-/. " %%i in ("%day%") do (
set /a sy=%%i, sm=100%%j %% 100, sd=100%%k %% 100
)
set /a sd-=input
if %sd% leq 0 call :count
cls&echo.&echo.
echo 當前日期是：%day%
echo.
set sm=0%sm%
set sd=0%sd%
echo %input% 天前的日期是：%sy%-%sm:~-2%-%sd:~-2%
pause>nul
goto Main

:count
set /a sm-=1
if !sm! equ 0 set /a sm=12, sy-=1
call :days
set /a sd+=days
if %sd% leq 0 goto count
goto :eof

:days
:: 獲取指定月份的總天數
set /a leap="^!(sy %% 4) & ^!(^!(sy %% 100)) | ^!(sy %% 400)"
set /a max=28+leap
for /f "tokens=%sm%" %%i in ("31 %max% 31 30 31 30 31 31 30 31 30 31") do set days=%%i
goto :eof
[/code]

回覆:[Windows]如何定時自動備份整個網站目錄到遠端伺服器

starzine — GMT

:thumbup:謝謝你，還蠻實用的，另外，想再請問一下，如何在dos底下，取出星期幾呢？應該是說，如何用date來取出星期？，目前已經研究出N天前的寫法，不過想再問一下是可否知道哪一天是星期幾？謝謝！

回覆:[Windows]如何定時自動備份整個網站目錄到遠端伺服器

andowson — GMT

可以用下面的DOS指令取出目前的系統日期是星期幾
echo %date:~-3%
如果是要找出前N天是星期幾的話，可以先將系統日期暫存，然後改為前N天的日期，呼叫上面的指令即可取得星期幾，然後再將系統日期改回去。
[code=bat]@echo off
set prevday=2009/10/04
set today=%date:~0,10%
date %prevday%
echo %date:~-3%
date %today%[/code]
參考資料：
http://www.cnblogs.com/ustcyier/archive/2008/04/14/1152303.html

回覆:[Windows]如何定時自動備份整個網站目錄到遠端伺服器

starzine — GMT

:thumbup:感謝～謝謝您幫我找到這個答案。最後想請問，一般工作日跟放假日，應該都是用比較高階的程式才能寫出來的吧？！Dos能夠寫出這樣的批次檔嗎？也就是說，能夠分辨營業日跟放假日嗎？一般的放假日（ex.六、日）這個部分可以克服（ex.抓取星期幾？），但是，若是遇到其他的假日（ex.中秋節）不是在六日的話，這樣好像就沒辦法了。謝謝！

回覆:[Windows]如何定時自動備份整個網站目錄到遠端伺服器

andowson — GMT

我想山不轉路轉吧，可以用這樣的方式來達成，
1.手動建立一個假日檔，例如檔名取叫holidays.txt，每行一個日期，樣子如下：
2009/10/03
2009/12/25

2.從假日檔中每次讀取一行跟前N天的日期作比對，如果相同表示該前N天的日期即為假日，輸出 is a holiday的訊息

底下是範例的程式碼：
[code=bat]
@echo off
set prevday=2009/10/03
set isHoliday=0
for /f %%i in (holidays.txt) do call :checkHoliday %prevday% %%i
if %isHoliday%==1 (
echo %prevday% is a holiday
)
goto :end

:checkHoliday
if %1==%2 (
set isHoliday=1
)

:end
[/code]

[Windows]如何定時自動備份整個網站目錄到遠端伺服器

starzine — GMT

您好，不好意思，又有問題想請教。
目前遇到ftp server的密碼為空白
想請問一下cfg檔中的password若為空白時，該如何處理呢？謝謝！

回覆:[Windows]如何定時自動備份整個網站目錄到遠端伺服器

andowson — GMT

據我所知，除非您是使用TFTP(Trivial File Transfer Protocol) Server，才不需要驗證，否則
不用密碼就可以登入FTP Server :shock:好像不太可能（至少違反安全性，應該很難持續這種狀態），就算是匿名(Anonymous) FTP也是要輸入一下e-mail當作密碼的。

如果您的系統真的不用輸入密碼，可以試試看將ftp.cfg編輯成類似下列的樣子，試試看有什麼錯誤訊息再回報吧：
[code]remotehost username [/code]

參考文件：
http://www.sinica.edu.tw/ccc/sysinfo/desktop/ftp.pdf
http://en.wikipedia.org/wiki/Trivial_File_Transfer_Protocol

回覆:[Windows]如何定時自動備份整個網站目錄到遠端伺服器

starzine — GMT

謝謝大大，您說的那個cfg我已經試過了，他是會在命令提示字元中出現password的字樣，也就是還是要請我們填入密碼，而若是在cfg中填入'' 或""，則是會出現錯誤訊息（也就是密碼錯誤），後來呢！就只能請對方設定帳號密碼，才能解決這個問題，不過呢！還是很謝謝大大的！

不過，還是有一件事想請問大大，不曉得大大有沒有玩過Windows server 2008呢？在做排定的工作時（排程），沒有辦法順利執行成功（也就是使用7-zip壓縮時，無法順利以排程完成工作），但權限的部份已經設定為最高權限了，不曉得是否還有什麼原因呢？謝謝囉！

[Windows]如何定時自動備份整個網站目錄到遠端伺服器

n5998744 — GMT

您好,想請教老師:
如果我只想把備份的檔案放到同一台電腦的其他槽區而已,那應該要改哪裡?
再請問老師,資料庫的資料可以如何自動備份 ?
非常感謝!!

回覆:[Windows]如何定時自動備份整個網站目錄到遠端伺服器

andowson — GMT

n5998744您好:
如果只要把備份的檔案放到同一台電腦的其他槽區而已=>就是不作FTP的動作囉？
那就把ftpsession那段跳過去即可，可以修改remote_backup_web.bat的第34行
[code=bat;first-line:34]
goto ftpsession
[/code]
為
[code=bat;first-line:34]
goto end
[/code]
如果要更改備份檔所在的目錄，可以修改第21行
[code=bat;first-line:21]
set BACKUPDIR=D:\backup
[/code]

不知道您是使用何種資料庫軟體，如果是使用MS SQL Server，要備份資料庫到本機硬碟的話就很簡單，可以在資料庫軟體上設定排程，將資料庫備份到某一個目錄下即可。

回覆:[Windows]如何定時自動備份整個網站目錄到遠端伺服器

starzine — GMT

[color=darkblue]您好：因為又遇到了點難題，想來請教一下是否有任何可以解決的方法。

目前以cfg的檔案抓取資料都沒有問題，但是目前對方把ftp移至安全環境底下
開啟了相關的port如下：
HTTP安全連線：https-443
FTP安全連線：ftp-21(也有支援安全通道)、ftps-990(也可用此安全通道連線)
FTP被動模式：port-50000~50009
SSL認證：990, 989
SFTP：22
FTP傳輸資料：20

而因為這樣，目前所使用的cfg無法連接上，用一般的FTP軟體也沒有辦法（雖然有提供21port，但似乎是因為沒有安全性，所以被拒絕了）
請問cfg的部分應該怎麼處理呢？謝謝！[/color]

回覆:[Windows]如何定時自動備份整個網站目錄到遠端伺服器

andowson — GMT

試著改用[url=http://the.earth.li/~sgtatham/putty/latest/x86/psftp.exe]psftp[/url]這個程式來執行SFTP的工作看看
將原先使用ftp的指令改為psftp指令，下載後將psftp.exe放在remote_backup_web.bat相同目錄即可。
remote_backup_web.bat:
[code=batch]
@echo off
rem ---------------------------------------------------------------------------
rem Backup web application to remote host
rem
rem $Id: remote_backup_web.bat 2011-10-20 07:10:58 andowson $
rem ---------------------------------------------------------------------------

rem Find out Windows version
for /f "tokens=1-2 delims=[" %%i in ('ver') do echo %%j > ver1.txt
for /f "tokens=1-2 delims= " %%i in (ver1.txt) do echo %%j > ver2.txt
for /f "tokens=1 delims=]" %%i in (ver2.txt) do set vers=%%i
del ver1.txt
del ver2.txt
if %vers% GEQ 6 goto ver6

rem Find out web server's IP address
ipconfig | findstr "Address" > ip1.txt
for /f "tokens=1-2 delims=:" %%i in (ip1.txt) do echo %%j > ip2.txt
for /f "tokens=1-2 delims= " %%i in (ip2.txt) do (set ip=%%i)
del ip1.txt
del ip2.txt
goto common

:ver6
rem Find out web server's IP address
ipconfig | findstr "IPv4 位址" > ip1.txt
for /f "tokens=1-2 delims=:" %%i in (ip1.txt) do echo %%j > ip2.txt
for /f "tokens=1-2 delims= " %%i in (ip2.txt) do (set ip=%%i)
del ip1.txt
del ip2.txt

:common
rem Get today's year, month, day
for /f "tokens=1-3 delims=/ " %%a in ('date /t') do (set year=%%a& set month=%%b& set day=%%c)

rem Modify the following line for your environment
set TARGETNAME=demoweb
set TARGET=C:\Inetpub\wwwroot\%TARGETNAME%
set BACKUPDIR=D:\backup
set BACKUPFILE=%BACKUPDIR%\%year%\%TARGETNAME%_%ip%_%year%%month%%day%.zip
set LOGFILE=%TARGETNAME%_backup.log
set ZIPPASSWORD=secret

echo. | date | findstr "現在日期" >> %LOGFILE%
echo. | time | findstr "現在時間" >> %LOGFILE%

rem Compress the target directory with encryption password before ftp
"C:\Program Files\7-Zip\7z.exe" a -p%ZIPPASSWORD% %BACKUPFILE% %TARGET%\* >> %LOGFILE%

if not exist %BACKUPDIR%\%year% mkdir %BACKUPDIR%\%year%

if not exist %BACKUPFILE% goto nofile
goto ftpsession

:nofile
echo [FAILURE] File not found: %BACKUPFILE% >> %LOGFILE%
echo.>> %LOGFILE%
goto end

:ftpsession
for /f "tokens=1-3 delims= " %%i in (ftp.cfg) do (set FTPSERVER=%%i&set USERNAME=%%j&set PASSWORD=%%k)
echo mkdir %year%%month%%day% > ftpscript.txt
echo cd %year%%month%%day% >> ftpscript.txt
echo put %BACKUPFILE% >> ftpscript.txt
echo bye >> ftpscript.txt

echo ---=== ftp session begin ===--->> %LOGFILE%
echo ftp %BACKUPFILE% to %FTPSERVER% >> %LOGFILE%

psftp %FTPSERVER% -l %USERNAME% -pw %PASSWORD% -be -b ftpscript.txt >> %LOGFILE%

echo ---=== ftp session end ===--->> %LOGFILE%
echo. |time | findstr "現在時間">> %LOGFILE%
echo.>> %LOGFILE%

del ftpscript.txt

set TARGET=
set TARGETNAME=
set BACKUPDIR=
set BACKUPFILE=
set LOGFILE=
set ZIPPASSWORD=
set FTPSERVER=
set USERNAME=
set PASSWORD=

:end
[/code]

ftp.cfg可以使用原來的格式，也是放在跟remote_backup_web.bat相同目錄下:
[code]remote_sftp_server username password[/code]

最後先開啟一個CMD命令視窗，然後利用cd切換工作目錄到存放remote_backup_web.bat的目錄下
手動執行一次remote_backup_web.bat，測試是否可以正常運作。因為第一次連線至SFTP Server需要驗證主機端的憑證，會詢問是否要儲存遠端主機的key，選擇yes。

有關psftp的使用說明請參考下列網址:
http://libai.math.ncu.edu.tw/bcc16/6/putty/psftp.html

註:本batch script中含有部份中文字串，存檔時請注意選擇編碼為ANSI/Windows

回覆:[Windows]如何定時自動備份整個網站目錄到遠端伺服器

starzine — GMT

[color=darkblue]大大您好：

不好意思又有問題想請教，因為對DOS的指令實在是很不熟悉。
因為需要在FTP中的各個資料夾中抓取所需的資料，
所以需要A資料夾抓完後，再到上一層資料夾，再至B資料夾。
原本想說可以把要抓的資料夾寫成一個txt檔，就像大大上面寫的holiday.txt一樣。
不過在FTP中，好像不太能用for這個語法。

我的寫法如下：
echo lcd %BACKUPDIR% >> ftpscript.txt
for /f "tokens=1-50 delims= " %%i in (pbank.txt) do(
echo cd %FTPDIR%>>ftpscript.txt
echo mget *%year%%month%%day%.*>> ftpscript.txt
echo cd \>> ftpscript.txt
)
目前FTP好像到這一段就不跑了。

所以可否請看看還有沒有什麼辦法？
感謝！[/color]

回覆:[Windows]如何定時自動備份整個網站目錄到遠端伺服器

andowson — GMT

starzine您好，
看起來你的for迴圈那段有點問題，如果你是一行一筆資料的話，請參考先前我的holiday.bat裡面的寫法。
[code=batch]
echo lcd %BACKUPDIR% >> ftpscript.txt
echo prompt >> ftpscript.txt
for /f %%i in (pbank.txt) do (
echo cd %%i >>ftpscript.txt
echo mget *%year%%month%%day%.* >> ftpscript.txt
echo cd .. >> ftpscript.txt
)
[/code]
又你可以先把你的測試程式寫成一個小bat檔，測試看看能不能動，再貼回原來的主程式去。

回覆:[Windows]如何定時自動備份整個網站目錄到遠端伺服器

starzine — GMT

大大您好：

感謝您的回答，不過因為您寫的那個holiday.bat...我其實看不是很懂，可否請您稍微解釋一下呢？麻煩您了！

[color=blue][/color]

回覆:[Windows]如何定時自動備份整個網站目錄到遠端伺服器

andowson — GMT

我的意思是指如果您想要拜訪(visit)holidays.txt檔案中每一行的資料時，只要寫成下面的 for迴圈即可:
[code=batch]@echo off
for /f %%i in (holidays.txt) do (
echo %%i is a holiday
)[/code]
[color=red]%%i[/color] 就是迴圈每前進一圈時，由holidays.txt所讀出的下一筆資料
假設holidays.txt內容如下
[code=text]2011/1/1
2011/2/2
2011/2/28
2011/4/4
2011/4/5
2011/6/6
2011/9/12
2011/10/10[/code]
將會依序印出:
[code=text]2011/1/1 is a holiday
2011/2/2 is a holiday
2011/2/28 is a holiday
2011/4/4 is a holiday
2011/4/5 is a holiday
2011/6/6 is a holiday
2011/9/12 is a holiday
2011/10/10 is a holiday[/code]

回覆:[Windows]如何定時自動備份整個網站目錄到遠端伺服器

starzine — GMT

[quote=andowson]我的意思是指如果您想要拜訪(visit)holidays.txt檔案中每一行的資料時，只要寫成下面的 for迴圈即可:
[code=batch]@echo off
for /f %%i in (holidays.txt) do (
echo %%i is a holiday
)[/code]
[color=red]%%i[/color] 就是迴圈每前進一圈時，由holidays.txt所讀出的下一筆資料
假設holidays.txt內容如下
[code=text]2011/1/1
2011/2/2
2011/2/28
2011/4/4
2011/4/5
2011/6/6
2011/9/12
2011/10/10[/code]
將會依序印出:
[code=text]2011/1/1 is a holiday
2011/2/2 is a holiday
2011/2/28 is a holiday
2011/4/4 is a holiday
2011/4/5 is a holiday
2011/6/6 is a holiday
2011/9/12 is a holiday
2011/10/10 is a holiday[/code][/quote]

不好意思大大：

我還是不太明白，那這個@echo off可以寫在FTP裡面嗎？
因為我寫了一個小批次後，還是不太能夠work...
例如：
@echo off
for /f %%i in (pbank.txt) do(
echo %%i
)
寫了do之後，按了以後，do不能用。
另外%%i可否變成%%m?
真的很抱歉，麻煩您再協助一下！

回覆:[Windows]如何定時自動備份整個網站目錄到遠端伺服器

andowson — GMT

starzine您好:
還是老話一句，請仔細觀察我的範例程式，細節就是魔鬼啦:
將您的小批次檔存檔為test.bat，利用cmd開啟一個DOS 命令視窗後，執行test，顯示下列的錯誤訊息
[quote]這個時候不應有 do(。[/quote]
不知道您有沒有發現，我的範例程式do和(中間有空一格?
將do(改為do (後，test.bat就可以正常執行了(前提是假設pbank.txt存在啦)

另外，%%i可否變成%%m?
這個當然是可以的，不過要改完整就是了，不要只改到一個地方:
[code=batch]@echo off
for /f %%m in (pbank.txt) do (
echo %%m
)[/code]

最後我不清楚你問的@echo off可以寫在FTP裡面嗎？這裡的FTP是指ftpscript.txt嗎?

回覆:[Windows]如何定時自動備份整個網站目錄到遠端伺服器

starzine — GMT

[color=darkblue]大大您好：
不好意思又打擾了，
有兩個問題
我把.txt檔寫在FTP中。大概如下[/color]
[code=batch]
echo open %FTPSERVER% > ftpscript.txt
echo user %USERNAME% %PASSWORD% >> ftpscript.txt
echo lcd %BACKUPDIR% >> ftpscript.txt
for /f %%m in (pbank.txt) do (
echo cd %%m>>ftpscript.txt
rem echo mget *%year%%month%%day%.*>> ftpscript.txt
echo mget *.*>> ftpscript.txt
echo cd \>> ftpscript.txt
)
echo cd %FTPDIR2%>>ftpscript.txt
echo mget *%year%%month%%day%.*>> ftpscript.txt
rem echo get *.*>> ftpscript.txt
echo dir *%year%%month%%day%.*>> ftpscript.txt
rem echo mget *.*>> ftpscript.txt
echo bye >> ftpscript.txt
echo ---=== ftp session begins ===--->> %LOGFILE%
echo ftp %FTPSERVER% to %BACKUPDIR% >> %LOGFILE%
echo mget *%year%%month%%day%.*>>%LOGFILE%
[/code]
[color=darkblue]我的想法是，迴圈再進入該資料夾後，抓取所有的資料完畢，再回上一層，然後再進入下一個資料夾。而log檔案的確是有進入每一個資料夾，但是卻沒有辦法抓取任何的檔案。想請問是否有哪裡有錯誤？
另外一個問題是，可否抓取系統日的資料呢？（因為無法從資料檔名來做區別，所以可否以系統日的資料來抓取？）
不好意思，打擾了。[/color]

回覆:[Windows]如何定時自動備份整個網站目錄到遠端伺服器

andowson — GMT

starzine您好:
可否先將bat檔中的這一行註解掉:
[code=bat]del ftpscript.txt[/code]
方法就是前面加上rem，如下:
[code=bat]rem del ftpscript.txt[/code]
然後你再執行一次，接著你把ftpscript.txt和log檔都傳上來，比較方便除錯，謝謝~

回覆:[Windows]如何定時自動備份整個網站目錄到遠端伺服器

starzine — GMT

[quote=andowson]starzine您好:
可否先將bat檔中的這一行註解掉:
[code=bat]del ftpscript.txt[/code]
方法就是前面加上rem，如下:
[code=bat]rem del ftpscript.txt[/code]
然後你再執行一次，接著你把ftpscript.txt和log檔都傳上來，比較方便除錯，謝謝~
[/quote]
大大您好：
我的整個程式是這樣的寫法
[code=bat]
@echo off
set BACKUPDIR=s:\upload
set BACKUPDIR2=s:\uploadbackup
set BACKUPFILE=%BACKUPDIR2%\%year%%month%%day%
set FTPDIR2=FundX
set LOGFILE=%year%%month%%day%_backup.log

echo wscript.echo dateadd("d",-2,date) >%tmp%\tmp.vbs
for /f "tokens=1-3 delims=/ " %%a in ('cscript /nologo %tmp%\tmp.vbs') do (set year=%%a& set month=%%b& set day=%%c)
if %month% LEQ 9 set month=0%month%
if %day% LEQ 9 set day=0%day%

echo. | date | findstr "現在日期" >> %LOGFILE%
echo. | time | findstr "現在時間" >> %LOGFILE%

:ftpsession
for /f "tokens=1-3 delims= " %%i in (ftp.cfg) do (set FTPSERVER=%%i&set USERNAME=%%j&set PASSWORD=%%k)

echo open %FTPSERVER% > ftpscript.txt
echo user %USERNAME% %PASSWORD% >> ftpscript.txt
echo lcd %BACKUPDIR% >> ftpscript.txt
for /f %%m in (pbank.txt) do (
echo cd %%m>>ftpscript.txt
echo mget *%year%%month%%day%.*>> ftpscript.txt
rem echo mget *.*>> ftpscript.txt
echo cd \>> ftpscript.txt
)
echo cd %FTPDIR2%>>ftpscript.txt
echo mget *%year%%month%%day%.*>> ftpscript.txt
rem echo get *.*>> ftpscript.txt
echo dir *%year%%month%%day%.*>> ftpscript.txt
rem echo mget *.*>> ftpscript.txt
echo bye >> ftpscript.txt
echo ---=== ftp session begins ===--->> %LOGFILE%
echo ftp %FTPSERVER% to %BACKUPDIR% >> %LOGFILE%
echo mget *%year%%month%%day%.*>>%LOGFILE%

psftp %FTPSERVER% -l %USERNAME% -pw %PASSWORD% -be -b ftpscript.txt >> %LOGFILE%

xcopy s:\upload\*%year%%month%%day%.* S:\uploadbackup /E/C/Q/R/Y
xcopy s:\upload\*.* S:\uploadbackup /E/C/Q/R/Y
if not exist %BACKUPDIR2%\%year%%month%%day% mkdir %BACKUPDIR2%\%year%%month%%day%
move /Y s:\uploadbackup\*%year%%month%%day%.* %BACKUPDIR2%\%year%%month%%day%
move /Y s:\uploadbackup\*.* %BACKUPDIR2%\%year%%month%%day%

echo ---=== ftp session ends ===--->> %LOGFILE%
echo. |time | findstr "現在時間">> %LOGFILE%
echo %BACKUPDIR2%\%year%%month%%day%>> %LOGFILE%
echo %BACKUPFILE1%>> %LOGFILE%
echo.>> %LOGFILE%
rem del ftpscript.txt
rem del %LOGFILE%_backup.log
move /Y I:\wSTN_IO\_backup.log %BACKUPDIR2%\%year%%month%%day%
move /Y I:\wSTN_IO\ftpscript.txt %BACKUPDIR2%\%year%%month%%day%

set TARGET=
set TARGETNAME=
set BACKUPDIR=
set BACKUPFILE=
set LOGFILE=
set FTPSERVER=
set USERNAME=
set PASSWORD=
:end
[/code]
那關於ftpscript.txt是這樣
[code=bat]
open 61.66.19X.XXX
user S00XX S0XXX
lcd s:\upload
cd A0001
mget *20120104.*
cd \
cd A0002
mget *20120104.*
cd \
cd A0003
mget *20120104.*
cd \
cd A0004
mget *20120104.*
cd \
cd A0005
mget *20120104.*
cd \
cd A0006
mget *20120104.*
cd \
cd A0007
mget *20120104.*
cd \
cd A0008
mget *20120104.*
cd \
cd A0009
mget *20120104.*
cd \
cd A0010
mget *20120104.*
cd \
cd A0011
mget *20120104.*
cd \
cd A0012
mget *20120104.*
cd \
cd A0013
mget *20120104.*
cd \
cd A0014
mget *20120104.*
cd \
cd A0015
mget *20120104.*
cd \
cd A0016
mget *20120104.*
cd \
cd A0017
mget *20120104.*
cd \
cd A0018
mget *20120104.*
cd \
cd A0019
mget *20120104.*
cd \
cd A0020
mget *20120104.*
cd \
cd A0021
mget *20120104.*
cd \
cd A0022
mget *20120104.*
cd \
cd A0023
mget *20120104.*
cd \
cd A0024
mget *20120104.*
cd \
cd A0025
mget *20120104.*
cd \
cd A0026
mget *20120104.*
cd \
cd A0027
mget *20120104.*
cd \
cd A0028
mget *20120104.*
cd \
cd A0029
mget *20120104.*
cd \
cd A0030
mget *20120104.*
cd \
cd A0031
mget *20120104.*
cd \
cd A0032
mget *20120104.*
cd \
cd A0033
mget *20120104.*
cd \
cd A0034
mget *20120104.*
cd \
cd A0035
mget *20120104.*
cd \
cd A0036
mget *20120104.*
cd \
cd A0037
mget *20120104.*
cd \
cd A0038
mget *20120104.*
cd \
cd A0039
mget *20120104.*
cd \
cd A0040
mget *20120104.*
cd \
cd A0041
mget *20120104.*
cd \
cd A0042
mget *20120104.*
cd \
cd A0043
mget *20120104.*
cd \
cd A0044
mget *20120104.*
cd \
cd A0045
mget *20120104.*
cd \
cd A0046
mget *20120104.*
cd \
cd A0047
mget *20120104.*
cd \
cd A0048
mget *20120104.*
cd \
cd A0049
mget *20120104.*
cd \
cd A0099
mget *20120104.*
cd \
cd FundX
mget *20120104.*
dir *20120104.*
bye
[/code]
有兩個問題
1. 在執行這個.bat檔時，似乎沒辦法執行完畢。
2. 也沒有相關的log記錄。
可是從ftpscript.txt來看，應該是有跑了每一個資料夾。
但是卻沒有將任何資料下載下來。
這是很奇怪的一件事。
再麻煩大大了！

回覆:[Windows]如何定時自動備份整個網站目錄到遠端伺服器

andowson — GMT

初步修正如下:
[code=bat]@echo off
echo wscript.echo dateadd("d",-2,date) >%tmp%\tmp.vbs
for /f "tokens=1-3 delims=/ " %%a in ('cscript /nologo %tmp%\tmp.vbs') do (set year=%%a& set month=%%b& set day=%%c)
if %month% LEQ 9 set month=0%month%
if %day% LEQ 9 set day=0%day%
rem 去掉字串尾端空白
set day=%day:~,2%

set BACKUPDIR=s:\upload
set BACKUPDIR2=s:\uploadbackup
set BACKUPFILE=%BACKUPDIR2%\%year%%month%%day%
set FTPDIR2=FundX
set LOGFILE=%year%%month%%day%_backup.log
echo %LOGFILE%
echo. | date | findstr "現在日期" >> %LOGFILE%
echo. | time | findstr "現在時間" >> %LOGFILE%

:ftpsession
for /f "tokens=1-3 delims= " %%i in (ftp.cfg) do (set FTPSERVER=%%i&set USERNAME=%%j&set PASSWORD=%%k)

rem echo open %FTPSERVER% > ftpscript.txt
rem echo user %USERNAME% %PASSWORD% >> ftpscript.txt
echo lcd %BACKUPDIR% > ftpscript.txt
for /f %%m in (pbank.txt) do (
echo cd %%m>>ftpscript.txt
echo mget *%year%%month%%day%.*>> ftpscript.txt
rem echo mget *.*>> ftpscript.txt
echo cd ..>> ftpscript.txt
)
echo cd %FTPDIR2%>>ftpscript.txt
echo mget *%year%%month%%day%.*>> ftpscript.txt
rem echo get *.*>> ftpscript.txt
echo dir *%year%%month%%day%.*>> ftpscript.txt
rem echo mget *.*>> ftpscript.txt
echo bye >> ftpscript.txt
echo ---=== ftp session begins ===--->> %LOGFILE%
echo ftp %FTPSERVER% to %BACKUPDIR% >> %LOGFILE%
echo mget *%year%%month%%day%.*>>%LOGFILE%

psftp %FTPSERVER% -l %USERNAME% -pw %PASSWORD% -be -b ftpscript.txt >> %LOGFILE%

xcopy %BACKUPDIR%\*%year%%month%%day%.* %BACKUPDIR2% /E/C/Q/R/Y
xcopy %BACKUPDIR%\*.* %BACKUPDIR2% /E/C/Q/R/Y
if not exist %BACKUPDIR2%\%year%%month%%day% mkdir %BACKUPDIR2%\%year%%month%%day%
move /Y %BACKUPDIR2%\*%year%%month%%day%.* %BACKUPDIR2%\%year%%month%%day%
move /Y %BACKUPDIR2%\*.* %BACKUPDIR2%\%year%%month%%day%

echo ---=== ftp session ends ===--->> %LOGFILE%
echo. |time | findstr "現在時間">> %LOGFILE%
echo %BACKUPDIR2%\%year%%month%%day%>> %LOGFILE%
echo %BACKUPFILE1%>> %LOGFILE%
echo.>> %LOGFILE%
rem del ftpscript.txt
rem del %LOGFILE%
move /Y I:\wSTN_IO\%LOGFILE% %BACKUPDIR2%\%year%%month%%day%
move /Y I:\wSTN_IO\ftpscript.txt %BACKUPDIR2%\%year%%month%%day%

set TARGET=
set TARGETNAME=
set BACKUPDIR=
set BACKUPFILE=
set LOGFILE=
set FTPSERVER=
set USERNAME=
set PASSWORD=
:end[/code]

說明如下:
將原8~11行搬移至第2行以取得year month day變數的定義
[color=red]增加第7行, 修正day變數尾端有空白字串的bug[/color]
刪除(這裡我先用rem註解掉)原程式中的19-20行
[code]rem echo open %FTPSERVER% > ftpscript.txt
rem echo user %USERNAME% %PASSWORD% >> ftpscript.txt[/code]
同時修改原第21行如下:
[code]echo lcd %BACKUPDIR% > ftpscript.txt[/code]
另外我不知道你用cd \的原因為何，是否可以試著把cd \ 改為cd ..
將原第26行改為
[code]echo cd ..>> ftpscript.txt[/code]

參考資料:
[url=http://tw.myblog.yahoo.com/blue-comic/article?mid=451&prev=541&l=f&fid=25]幾個在寫 MS-DOS batch script 時好用的動作[/url]

回覆:[Windows]如何定時自動備份整個網站目錄到遠端伺服器

starzine — GMT

說明如下:
將原8~11行搬移至第2行以取得year month day變數的定義
[color=red]增加第7行, 修正day變數尾端有空白字串的bug[/color]
刪除(這裡我先用rem註解掉)原程式中的19-20行
[code]rem echo open %FTPSERVER% > ftpscript.txt
rem echo user %USERNAME% %PASSWORD% >> ftpscript.txt[/code]
同時修改原第21行如下:
[code]echo lcd %BACKUPDIR% > ftpscript.txt[/code]
另外我不知道你用cd \的原因為何，是否可以試著把cd \ 改為cd ..
將原第26行改為
[code]echo cd ..>> ftpscript.txt[/code]

參考資料:
[url=http://tw.myblog.yahoo.com/blue-comic/article?mid=451&prev=541&l=f&fid=25]幾個在寫 MS-DOS batch script 時好用的動作[/url][/quote]

大大您好：
謝謝您的建議，我會把程式再稍做修改。
但有一個問題想請教，要如何抓取系統日的檔案呢？
也就是說，如果今天是1/9日，我想抓取修改日期是1/6日的資料，但檔案名稱不見得是0106的資料。
請問有辦法可以做的到嗎？
還有，若是有這樣的問題時，若在Google上欲搜尋，應該下什麼樣的關鍵字呢？
麻煩您囉！

回覆:[Windows]如何定時自動備份整個網站目錄到遠端伺服器

andowson — GMT

您可以參考下面的範例程式去修改
[code=bat]@echo off
rem 取得系統日期
for /f "tokens=1 delims= " %%a in ('date /T') do set today=%%a

rem 先找出現行目錄下所有檔案並依日期排序後再過濾出日期為系統日期之檔案存到dir.txt
dir /A:-D /O:D | find /i "%today%" > dir.txt

if exist filelist.txt del filelist.txt
rem 利用空白字元切割，由dir.txt每列的第五欄中取得檔案名稱
for /f "tokens=5 delims= " %%a in (dir.txt) do (
echo %%a >> filelist.txt
rem 下面可以開始抓檔案了
rem get %%a
)[/code]

我是利用[google]DOS file date[/google]這樣子的關鍵字去搜尋的
參考資料:
http://www.computing.net/answers/dos/dos-batch-to-check-file-date/12627.html

回覆:[Windows]如何定時自動備份整個網站目錄到遠端伺服器

starzine — GMT

[quote=andowson]
另外我不知道你用cd \的原因為何，是否可以試著把cd \ 改為cd ..
將原第26行改為
[code]echo cd ..>> ftpscript.txt[/code][/quote]

[color=darkblue]大大您好：
謝謝您的協助，後來經過測試後，發現第26行改成這樣就行了[/color]
[code]echo cd >> ftpscript.txt[/code]
[color=red]也就是說psftp好像只懂得cd
而不懂得cd..或cd\[/color]

[color=darkblue]這也是經過實驗之後才得到的結果。

另外，關於系統日期的部分，
我是想要在透過psftp連線到遠端的主機上，得到遠端主機上每個資料夾的修改日期。
再以遠端主機上的資料夾以修改日期排序。
再進入各個資料夾中抓取該修改日期之資料
想抓取系統日期的前一天的資料，但其檔名不見得係以修改日期來命名。

不過發現psftp似乎沒有支援相關指令可以用日期來排序。

目前也只找到ls 和dir可以使用。
但是ls 及dir 似乎沒有更進階的指令來作為排序的動作。（ex.dir -D之類的）
好像都無法按照日期排序。
目前好像只能用資料夾名稱排序。

所以似乎沒辦法使用大大下方所寫的程式。
大大所提供的程式，是否只能適用於本機端呢？

還是說，還有什麼方法呢？
謝謝大大囉！[/color]

回覆:[Windows]如何定時自動備份整個網站目錄到遠端伺服器

andowson — GMT

starzine您好:
我給的範例確實是只能在本機端執行，取得本機端的檔案名稱，而您所需要的是取得遠端檔案伺服器目錄下的檔案清單。
可以在sftp下執行目錄排序的指令如下(日期最近的會排在上面)
ls -lt
但接下來可能你會問要如何從psftp將這個指令的結果(目錄內的檔案清單)傳回，好讓我們可以再加以過濾出某個日期範圍內的檔案?

你先想一下，好好的想一下.... :?

你不知道，我也不知道， :roll:
這個問題可能已經超出光靠DOS Batch語法就能完成的事情了。

還是再問一次，有沒有可能改為規範遠端檔案伺服器上檔案的命名方式，否則我想就只有老老實實去寫程式來處理會比較快。

當問題複雜到一個程度時，還是真得要寫個程式來執行這個任務。(如何寫這個程式我就不在這邊討論，可以參考[url]http://www.andowson.com/posts/list/199.page[/url])

回覆:[Windows]如何定時自動備份整個網站目錄到遠端伺服器

starzine — GMT

[quote=andowson]starzine您好:
我給的範例確實是只能在本機端執行，取得本機端的檔案名稱，而您所需要的是取得遠端檔案伺服器目錄下的檔案清單。
可以在sftp下執行目錄排序的指令如下(日期最近的會排在上面)
ls -lt
但接下來可能你會問要如何從psftp將這個指令的結果(目錄內的檔案清單)傳回，好讓我們可以再加以過濾出某個日期範圍內的檔案?

你先想一下，好好的想一下.... :?

你不知道，我也不知道， :roll:
這個問題可能已經超出光靠DOS Batch語法就能完成的事情了。

還是再問一次，有沒有可能改為規範遠端檔案伺服器上檔案的命名方式，否則我想就只有老老實實去寫程式來處理會比較快。

當問題複雜到一個程度時，還是真得要寫個程式來執行這個任務。(如何寫這個程式我就不在這邊討論，可以參考[url]http://www.andowson.com/posts/list/199.page[/url])

[/quote]

[color=darkblue]大大您好：
謝謝您的指教～
我想，這的確是有點難，可能需要寫程式來解決...
我來另外想辦法好了，謝謝您囉！
有機會再請教！ :lol:[/color]